Use Client as var type instead of singleton

Use this from the relay message

build.zig

@@ -15,6 +15,12 @@ pub fn build(b: *std.Build) void {
     // set a preferred release mode, allowing the user to decide how to optimize.
     const optimize = b.standardOptimizeOption(.{});
 
+    const lib_mod = b.createModule(.{
+        .root_source_file = b.path("src/root.zig"),
+        .target = target,
+        .optimize = optimize,
+    });
+
     // We will also create a module for our other entry point, 'main.zig'.
     const exe_mod = b.createModule(.{
         // `root_source_file` is the Zig "entry point" of the module. If a module
@@ -26,9 +32,20 @@ pub fn build(b: *std.Build) void {
         .optimize = optimize,
     });
 
-    exe_mod.addImport("network", b.dependency("network", .{}).module("network"));
+    lib_mod.addImport("network", b.dependency("network", .{}).module("network"));
+    lib_mod.addImport("gatorcat", b.dependency("gatorcat", .{}).module("gatorcat"));
+
+    exe_mod.addImport("zaprus", lib_mod);
     exe_mod.addImport("clap", b.dependency("clap", .{}).module("clap"));
 
+    const lib = b.addLibrary(.{
+        .linkage = .static,
+        .name = "zaprus",
+        .root_module = lib_mod,
+    });
+
+    b.installArtifact(lib);
+
     // This creates another `std.Build.Step.Compile`, but this one builds an executable
     // rather than a static library.
     const exe = b.addExecutable(.{

build.zig.zon

@@ -44,6 +44,10 @@
             .url = "git+https://github.com/Hejsil/zig-clap?ref=0.10.0#e47028deaefc2fb396d3d9e9f7bd776ae0b2a43a",
             .hash = "clap-0.10.0-oBajB434AQBDh-Ei3YtoKIRxZacVPF1iSwp3IX_ZB8f0",
         },
+        .gatorcat = .{
+            .url = "git+https://github.com/kj4tmp/gatorcat.git#0a97b666677501db4939e3e8245f88a19e015893",
+            .hash = "gatorcat-0.3.4-WcrpTcleBwCta_9TjomuIGb3bdg2Pke_FXI_WkMTEivH",
+        },
     },
     .paths = .{
         "build.zig",

src/Client.zig

@@ -0,0 +1,197 @@
+const base64Enc = std.base64.Base64Encoder.init(std.base64.standard_alphabet_chars, '=');
+const base64Dec = std.base64.Base64Decoder.init(std.base64.standard_alphabet_chars, '=');
+
+rand: Random,
+socket: gcat.nic.RawSocket,
+
+const Self = @This();
+
+const max_message_size = 2048;
+
+pub fn init(interface_name: [:0]const u8) !Self {
+    var prng = Random.DefaultPrng.init(blk: {
+        var seed: u64 = undefined;
+        try posix.getrandom(mem.asBytes(&seed));
+        break :blk seed;
+    });
+    const rand = prng.random();
+
+    const socket: gcat.nic.RawSocket = try .init(interface_name);
+
+    return .{
+        .rand = rand,
+        .socket = socket,
+    };
+}
+
+pub fn deinit(self: *Self) void {
+    self.socket.deinit();
+}
+
+/// Used for relay messages and connection handshake.
+/// Assumes Client .init has been called.
+fn broadcastInitialInterestMessage(self: *Self, msg_bytes: []align(@alignOf(SaprusMessage)) u8) !void {
+    var packet_bytes: [max_message_size]u8 = comptime blk: {
+        var b: [max_message_size]u8 = @splat(0);
+
+        // Destination MAC addr to FF:FF:FF:FF:FF:FF
+        for (0..6) |i| {
+            b[i] = 0xff;
+        }
+
+        // Set Ethernet type to IPv4
+        b[0x0c] = 0x08;
+        b[0x0d] = 0x00;
+
+        // Set IPv4 version to 4
+        b[0x0e] = 0x45;
+
+        // Destination broadcast
+        for (0x1e..0x22) |i| {
+            b[i] = 0xff;
+        }
+
+        // Set TTL
+        b[0x16] = 0x40;
+
+        // Set IPv4 protocol to UDP
+        b[0x17] = 0x11;
+
+        // Set interest filter value to 8888.
+        b[0x24] = 0x22;
+        b[0x25] = 0xb8;
+        break :blk b;
+    };
+    var msg: *SaprusMessage = try .bytesAsValue(msg_bytes);
+    try msg.networkFromNativeEndian();
+    defer msg.nativeFromNetworkEndian() catch unreachable;
+
+    // The byte position within the packet that the saprus message starts at.
+    const saprus_start_byte = 42;
+    @memcpy(packet_bytes[saprus_start_byte .. saprus_start_byte + msg_bytes.len], msg_bytes);
+
+    try self.socket.linkLayer().send(packet_bytes[0 .. saprus_start_byte + msg_bytes.len]);
+}
+
+// fn broadcastSaprusMessage(msg_bytes: []align(@alignOf(SaprusMessage)) u8) !void {}
+
+fn broadcastSaprusMessage(msg_bytes: []align(@alignOf(SaprusMessage)) u8, udp_port: u16) !void {
+    if (false) {
+        var foo: gcat.nic.RawSocket = try .init("enp7s0"); // /proc/net/dev
+        defer foo.deinit();
+    }
+    const msg: *SaprusMessage = try .bytesAsValue(msg_bytes);
+    try msg.networkFromNativeEndian();
+    defer msg.nativeFromNetworkEndian() catch unreachable;
+
+    var sock = try network.Socket.create(.ipv4, .udp);
+    defer sock.close();
+
+    try sock.setBroadcast(true);
+
+    // Bind to 0.0.0.0:0
+    const bind_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.any },
+        .port = 0,
+    };
+
+    const dest_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
+        .port = udp_port,
+    };
+
+    try sock.bind(bind_addr);
+
+    std.debug.print("{x}\n", .{msg_bytes});
+
+    _ = try sock.sendTo(dest_addr, msg_bytes);
+}
+
+pub fn sendRelay(self: *Self, payload: []const u8, dest: [4]u8) !void {
+    var buf: [max_message_size]u8 align(@alignOf(SaprusMessage)) = undefined;
+    const msg_bytes = buf[0..try SaprusMessage.calcSize(
+        .relay,
+        base64Enc.calcSize(payload.len),
+    )];
+    const msg: *SaprusMessage = .init(.relay, msg_bytes);
+
+    const relay = (try msg.getSaprusTypePayload()).relay;
+    relay.dest = dest;
+    _ = base64Enc.encode(relay.getPayload(), payload);
+
+    try self.broadcastInitialInterestMessage(msg_bytes);
+}
+
+fn randomPort(self: Self) u16 {
+    return self.rand.intRangeAtMost(u16, 1024, 65000);
+}
+
+pub fn sendInitialConnection(
+    self: Self,
+    payload: []const u8,
+    output_bytes: []align(@alignOf(SaprusMessage)) u8,
+    initial_port: u16,
+) !*SaprusMessage {
+    const dest_port = self.randomPort();
+    const msg_bytes = output_bytes[0..try SaprusMessage.calcSize(
+        .connection,
+        base64Enc.calcSize(payload.len),
+    )];
+    const msg: *SaprusMessage = .init(.connection, msg_bytes);
+
+    const connection = (try msg.getSaprusTypePayload()).connection;
+    connection.src_port = initial_port;
+    connection.dest_port = dest_port;
+    _ = base64Enc.encode(connection.getPayload(), payload);
+
+    try broadcastSaprusMessage(msg_bytes, 8888);
+
+    return msg;
+}
+
+pub fn connect(self: Self, payload: []const u8) !?SaprusConnection {
+    const initial_port = self.randomPort();
+
+    var initial_conn_res: ?*SaprusMessage = null;
+
+    var sock = try network.Socket.create(.ipv4, .udp);
+    defer sock.close();
+
+    // Bind to 255.255.255.255:8888
+    const bind_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
+        .port = 8888,
+    };
+
+    // timeout 1s
+    try sock.setReadTimeout(1 * std.time.us_per_s);
+    try sock.bind(bind_addr);
+
+    var sent_msg_bytes: [max_message_size]u8 align(@alignOf(SaprusMessage)) = undefined;
+    const msg = try self.sendInitialConnection(payload, &sent_msg_bytes, initial_port);
+
+    var response_buf: [max_message_size]u8 align(@alignOf(SaprusMessage)) = undefined;
+    _ = try sock.receive(&response_buf); // Ignore message that I sent.
+    const len = try sock.receive(&response_buf);
+
+    initial_conn_res = try .networkBytesAsValue(response_buf[0..len]);
+
+    // Complete handshake after awaiting response
+    try broadcastSaprusMessage(msg.asBytes(), self.randomPort());
+
+    if (false) {
+        return initial_conn_res.?;
+    }
+    return null;
+}
+
+const SaprusMessage = @import("message.zig").Message;
+const SaprusConnection = @import("Connection.zig");
+
+const std = @import("std");
+const Random = std.Random;
+const posix = std.posix;
+const mem = std.mem;
+
+const network = @import("network");
+const gcat = @import("gatorcat");

src/main.zig

@@ -23,6 +23,7 @@ pub fn main() !void {
     const params = comptime clap.parseParamsComptime(
         \\-h, --help           Display this help and exit.
         \\-r, --relay <str>    A relay message to send.
+        \\-d, --dest <str>     An IPv4 or <= 4 ASCII byte string.
         \\-c, --connect <str>  A connection message to send.
         \\
     );
@@ -41,40 +42,53 @@ pub fn main() !void {
     };
     defer res.deinit();
 
-    try Saprus.init();
-    defer Saprus.deinit();
-
     if (res.args.help != 0) {
         return clap.help(std.io.getStdErr().writer(), clap.Help, &params, .{});
     }
 
+    var client = try SaprusClient.init("enp7s0");
+    defer client.deinit();
+
     if (res.args.relay) |r| {
-        try Saprus.sendRelay(if (r.len > 0) r else "Hello darkness my old friend", gpa);
-        std.debug.print("Sent: {s}\n", .{r});
+        const dest = parseDest(res.args.dest);
+        try client.sendRelay(
+            if (r.len > 0) r else "Hello darkness my old friend",
+            dest,
+        );
+        // std.debug.print("Sent: {s}\n", .{r});
         return;
     } else if (res.args.connect) |c| {
-        const conn_res: ?SaprusMessage = Saprus.connect(if (c.len > 0) c else "Hello darkness my old friend", gpa) catch |err| switch (err) {
+        _ = client.connect(if (c.len > 0) c else "Hello darkness my old friend") catch |err| switch (err) {
             error.WouldBlock => null,
             else => return err,
         };
-        defer if (conn_res) |r| r.deinit(gpa);
-        if (conn_res) |r| {
-            std.debug.print("{s}\n", .{r.connection.payload});
-        } else {
-            std.debug.print("No response from connection request\n", .{});
-        }
         return;
     }
 
     return clap.help(std.io.getStdErr().writer(), clap.Help, &params, .{});
 }
 
+fn parseDest(in: ?[]const u8) [4]u8 {
+    if (in) |dest| {
+        if (dest.len <= 4) {
+            var res: [4]u8 = @splat(0);
+            @memcpy(res[0..dest.len], dest);
+            return res;
+        }
+
+        const addr = std.net.Ip4Address.parse(dest, 0) catch return "FAIL".*;
+        return @bitCast(addr.sa.addr);
+    }
+    return "zap\x00".*;
+}
+
 const builtin = @import("builtin");
 const std = @import("std");
 const DebugAllocator = std.heap.DebugAllocator(.{});
 const ArrayList = std.ArrayList;
 
-const Saprus = @import("./saprus.zig");
-const SaprusMessage = Saprus.SaprusMessage;
+const zaprus = @import("zaprus");
+const SaprusClient = zaprus.Client;
+const SaprusMessage = zaprus.Message;
 
 const clap = @import("clap");

src/message.zig

@@ -0,0 +1,317 @@
+/// Type tag for Message union.
+/// This is the first value in the actual packet sent over the network.
+pub const PacketType = enum(u16) {
+    relay = 0x003C,
+    file_transfer = 0x8888,
+    connection = 0x00E9,
+    _,
+};
+
+/// Reserved option values.
+/// Currently unused.
+pub const ConnectionOptions = packed struct(u8) {
+    opt1: bool = false,
+    opt2: bool = false,
+    opt3: bool = false,
+    opt4: bool = false,
+    opt5: bool = false,
+    opt6: bool = false,
+    opt7: bool = false,
+    opt8: bool = false,
+};
+
+pub const MessageTypeError = error{
+    NotImplementedSaprusType,
+    UnknownSaprusType,
+};
+pub const MessageParseError = MessageTypeError || error{
+    InvalidMessage,
+};
+
+// ZERO COPY STUFF
+// &payload could be a void value that is treated as a pointer to a [*]u8
+/// All Saprus messages
+pub const Message = packed struct {
+    const Relay = packed struct {
+        dest: @Vector(4, u8),
+        payload: void,
+
+        pub fn getPayload(self: *align(1) Relay) []u8 {
+            const len: *u16 = @ptrFromInt(@intFromPtr(self) - @sizeOf(u16));
+            return @as([*]u8, @ptrCast(&self.payload))[0 .. len.* - @bitSizeOf(Relay) / 8];
+        }
+    };
+    const Connection = packed struct {
+        src_port: u16, // random number > 1024
+        dest_port: u16, // random number > 1024
+        seq_num: u32 = 0,
+        msg_id: u32 = 0,
+        reserved: u8 = 0,
+        options: ConnectionOptions = .{},
+        payload: void,
+
+        pub fn getPayload(self: *align(1) Connection) []u8 {
+            const len: *u16 = @ptrFromInt(@intFromPtr(self) - @sizeOf(u16));
+            return @as([*]u8, @ptrCast(&self.payload))[0 .. len.* - @bitSizeOf(Connection) / 8];
+        }
+
+        fn nativeFromNetworkEndian(self: *align(1) Connection) void {
+            self.src_port = bigToNative(@TypeOf(self.src_port), self.src_port);
+            self.dest_port = bigToNative(@TypeOf(self.dest_port), self.dest_port);
+            self.seq_num = bigToNative(@TypeOf(self.seq_num), self.seq_num);
+            self.msg_id = bigToNative(@TypeOf(self.msg_id), self.msg_id);
+        }
+
+        fn networkFromNativeEndian(self: *align(1) Connection) void {
+            self.src_port = nativeToBig(@TypeOf(self.src_port), self.src_port);
+            self.dest_port = nativeToBig(@TypeOf(self.dest_port), self.dest_port);
+            self.seq_num = nativeToBig(@TypeOf(self.seq_num), self.seq_num);
+            self.msg_id = nativeToBig(@TypeOf(self.msg_id), self.msg_id);
+        }
+    };
+
+    const Self = @This();
+    const SelfBytes = []align(@alignOf(Self)) u8;
+
+    type: PacketType,
+    length: u16,
+    bytes: void = {},
+
+    /// Takes a byte slice, and returns a Message struct backed by the slice.
+    /// This properly initializes the top level headers within the slice.
+    /// This is used for creating new messages. For reading messages from the network,
+    /// see: networkBytesAsValue.
+    pub fn init(@"type": PacketType, bytes: []align(@alignOf(Self)) u8) *Self {
+        std.debug.assert(bytes.len >= @sizeOf(Self));
+        const res: *Self = @ptrCast(bytes.ptr);
+        res.type = @"type";
+        res.length = @intCast(bytes.len - @sizeOf(Self));
+        return res;
+    }
+
+    /// Compute the number of bytes required to store a given payload size for a given message type.
+    pub fn calcSize(comptime @"type": PacketType, payload_len: usize) MessageTypeError!u16 {
+        const header_size = @bitSizeOf(switch (@"type") {
+            .relay => Relay,
+            .connection => Connection,
+            .file_transfer => return MessageTypeError.NotImplementedSaprusType,
+            else => return MessageTypeError.UnknownSaprusType,
+        }) / 8;
+        return @intCast(payload_len + @sizeOf(Self) + header_size);
+    }
+
+    fn getRelay(self: *Self) *align(1) Relay {
+        return std.mem.bytesAsValue(Relay, &self.bytes);
+    }
+    fn getConnection(self: *Self) *align(1) Connection {
+        return std.mem.bytesAsValue(Connection, &self.bytes);
+    }
+
+    /// Access the message Saprus payload.
+    pub fn getSaprusTypePayload(self: *Self) MessageTypeError!(union(PacketType) {
+        relay: *align(1) Relay,
+        file_transfer: void,
+        connection: *align(1) Connection,
+    }) {
+        return switch (self.type) {
+            .relay => .{ .relay = self.getRelay() },
+            .connection => .{ .connection = self.getConnection() },
+            .file_transfer => MessageTypeError.NotImplementedSaprusType,
+            else => MessageTypeError.UnknownSaprusType,
+        };
+    }
+
+    /// Convert the message to native endianness from network endianness in-place.
+    pub fn nativeFromNetworkEndian(self: *Self) MessageTypeError!void {
+        self.type = @enumFromInt(bigToNative(
+            @typeInfo(@TypeOf(self.type)).@"enum".tag_type,
+            @intFromEnum(self.type),
+        ));
+        self.length = bigToNative(@TypeOf(self.length), self.length);
+        errdefer {
+            // If the payload specific headers fail, revert the top level header values
+            self.type = @enumFromInt(nativeToBig(
+                @typeInfo(@TypeOf(self.type)).@"enum".tag_type,
+                @intFromEnum(self.type),
+            ));
+            self.length = nativeToBig(@TypeOf(self.length), self.length);
+        }
+        switch (try self.getSaprusTypePayload()) {
+            .relay => {},
+            .connection => |*con| con.*.nativeFromNetworkEndian(),
+            // We know other values are unreachable,
+            // because they would have returned an error from the switch condition.
+            else => unreachable,
+        }
+    }
+
+    /// Convert the message to network endianness from native endianness in-place.
+    pub fn networkFromNativeEndian(self: *Self) MessageTypeError!void {
+        try switch (try self.getSaprusTypePayload()) {
+            .relay => {},
+            .connection => |*con| con.*.networkFromNativeEndian(),
+            .file_transfer => MessageTypeError.NotImplementedSaprusType,
+            else => MessageTypeError.UnknownSaprusType,
+        };
+        self.type = @enumFromInt(nativeToBig(
+            @typeInfo(@TypeOf(self.type)).@"enum".tag_type,
+            @intFromEnum(self.type),
+        ));
+        self.length = nativeToBig(@TypeOf(self.length), self.length);
+    }
+
+    /// Convert network endian bytes to a native endian value in-place.
+    pub fn networkBytesAsValue(bytes: SelfBytes) MessageParseError!*Self {
+        const res = std.mem.bytesAsValue(Self, bytes);
+        try res.nativeFromNetworkEndian();
+        return .bytesAsValue(bytes);
+    }
+
+    /// Create a structured view of the bytes without initializing the length or type,
+    /// and without converting the endianness.
+    pub fn bytesAsValue(bytes: SelfBytes) MessageParseError!*Self {
+        const res = std.mem.bytesAsValue(Self, bytes);
+        return switch (res.type) {
+            .relay, .connection => if (bytes.len == res.length + @sizeOf(Self))
+                res
+            else
+                MessageParseError.InvalidMessage,
+            .file_transfer => MessageParseError.NotImplementedSaprusType,
+            else => MessageParseError.UnknownSaprusType,
+        };
+    }
+
+    /// Deprecated.
+    /// If I need the bytes, I should just pass around the slice that is backing this to begin with.
+    pub fn asBytes(self: *Self) SelfBytes {
+        const size = @sizeOf(Self) + self.length;
+        return @as([*]align(@alignOf(Self)) u8, @ptrCast(self))[0..size];
+    }
+};
+
+test "testing variable length zero copy struct" {
+    {
+        // Relay test
+        const payload = "Hello darkness my old friend";
+        var msg_bytes: [try Message.calcSize(.relay, payload.len)]u8 align(@alignOf(Message)) = undefined;
+
+        // Create a view of the byte slice as a Message
+        const msg: *Message = .init(.relay, &msg_bytes);
+
+        {
+            // Set the message values
+            {
+                // These are both set by the init call.
+                // msg.type = .relay;
+                // msg.length = payload_len;
+            }
+            const relay = (try msg.getSaprusTypePayload()).relay;
+            relay.dest = .{ 1, 2, 3, 4 };
+            @memcpy(relay.getPayload(), payload);
+        }
+
+        {
+            // Print the message as hex using the network byte order
+            try msg.networkFromNativeEndian();
+            // We know the error from nativeFromNetworkEndian is unreachable because
+            // it would have returned an error from networkFromNativeEndian.
+            defer msg.nativeFromNetworkEndian() catch unreachable;
+            std.debug.print("relay network bytes: {x}\n", .{msg_bytes});
+            std.debug.print("bytes len: {d}\n", .{msg_bytes.len});
+        }
+
+        if (false) {
+            // Illegal behavior
+            std.debug.print("{any}\n", .{(try msg.getSaprusTypePayload()).connection});
+        }
+
+        try std.testing.expectEqualDeep(msg, try Message.bytesAsValue(msg.asBytes()));
+    }
+
+    {
+        // Connection test
+        const payload = "Hello darkness my old friend";
+        var msg_bytes: [try Message.calcSize(.connection, payload.len)]u8 align(@alignOf(Message)) = undefined;
+
+        // Create a view of the byte slice as a Message
+        const msg: *Message = .init(.connection, &msg_bytes);
+
+        {
+            // Initializing connection header values
+            const connection = (try msg.getSaprusTypePayload()).connection;
+            connection.src_port = 1;
+            connection.dest_port = 2;
+            connection.seq_num = 3;
+            connection.msg_id = 4;
+            connection.reserved = 5;
+            connection.options = @bitCast(@as(u8, 6));
+            @memcpy(connection.getPayload(), payload);
+        }
+
+        {
+            // Print the message as hex using the network byte order
+            try msg.networkFromNativeEndian();
+            // We know the error from nativeFromNetworkEndian is unreachable because
+            // it would have returned an error from networkFromNativeEndian.
+            defer msg.nativeFromNetworkEndian() catch unreachable;
+            std.debug.print("connection network bytes: {x}\n", .{msg_bytes});
+            std.debug.print("bytes len: {d}\n", .{msg_bytes.len});
+        }
+    }
+}
+
+const std = @import("std");
+const Allocator = std.mem.Allocator;
+
+const asBytes = std.mem.asBytes;
+const nativeToBig = std.mem.nativeToBig;
+const bigToNative = std.mem.bigToNative;
+
+test "Round trip Relay toBytes and fromBytes" {
+    if (false) {
+        const gpa = std.testing.allocator;
+        const msg = Message{
+            .relay = .{
+                .header = .{ .dest = .{ 255, 255, 255, 255 } },
+                .payload = "Hello darkness my old friend",
+            },
+        };
+
+        const to_bytes = try msg.toBytes(gpa);
+        defer gpa.free(to_bytes);
+
+        const from_bytes = try Message.fromBytes(to_bytes, gpa);
+        defer from_bytes.deinit(gpa);
+
+        try std.testing.expectEqualDeep(msg, from_bytes);
+    }
+    return error.SkipZigTest;
+}
+
+test "Round trip Connection toBytes and fromBytes" {
+    if (false) {
+        const gpa = std.testing.allocator;
+        const msg = Message{
+            .connection = .{
+                .header = .{
+                    .src_port = 0,
+                    .dest_port = 0,
+                },
+                .payload = "Hello darkness my old friend",
+            },
+        };
+
+        const to_bytes = try msg.toBytes(gpa);
+        defer gpa.free(to_bytes);
+
+        const from_bytes = try Message.fromBytes(to_bytes, gpa);
+        defer from_bytes.deinit(gpa);
+
+        try std.testing.expectEqualDeep(msg, from_bytes);
+    }
+    return error.SkipZigTest;
+}
+
+test {
+    std.testing.refAllDeclsRecursive(@This());
+}

src/root.zig

@@ -0,0 +1,4 @@
+pub const Client = @import("Client.zig");
+pub const Connection = @import("Connection.zig");
+
+pub usingnamespace @import("message.zig");

src/saprus.zig

@@ -1,124 +0,0 @@
-var rand: ?Random = null;
-
-pub fn init() !void {
-    var prng = Random.DefaultPrng.init(blk: {
-        var seed: u64 = undefined;
-        try posix.getrandom(mem.asBytes(&seed));
-        break :blk seed;
-    });
-    rand = prng.random();
-    try network.init();
-}
-
-pub fn deinit() void {
-    network.deinit();
-}
-
-fn broadcastSaprusMessage(msg: SaprusMessage, udp_port: u16, allocator: Allocator) !void {
-    const msg_bytes = try msg.toBytes(allocator);
-    defer allocator.free(msg_bytes);
-
-    var sock = try network.Socket.create(.ipv4, .udp);
-    defer sock.close();
-
-    try sock.setBroadcast(true);
-
-    // Bind to 0.0.0.0:0
-    const bind_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.any },
-        .port = 0,
-    };
-
-    const dest_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
-        .port = udp_port,
-    };
-
-    try sock.bind(bind_addr);
-
-    _ = try sock.sendTo(dest_addr, msg_bytes);
-}
-
-pub fn sendRelay(payload: []const u8, allocator: Allocator) !void {
-    const msg = SaprusMessage{
-        .relay = .{
-            .header = .{ .dest = .{ 255, 255, 255, 255 } },
-            .payload = payload,
-        },
-    };
-
-    try broadcastSaprusMessage(msg, 8888, allocator);
-}
-
-fn randomPort() u16 {
-    var p: u16 = 0;
-    if (rand) |r| {
-        p = r.intRangeAtMost(u16, 1024, 65000);
-    } else unreachable;
-
-    return p;
-}
-
-pub fn sendInitialConnection(payload: []const u8, initial_port: u16, allocator: Allocator) !SaprusMessage {
-    const dest_port = randomPort();
-    const msg = SaprusMessage{
-        .connection = .{
-            .header = .{
-                .src_port = initial_port,
-                .dest_port = dest_port,
-            },
-            .payload = payload,
-        },
-    };
-
-    try broadcastSaprusMessage(msg, 8888, allocator);
-
-    return msg;
-}
-
-pub fn connect(payload: []const u8, allocator: Allocator) !?SaprusMessage {
-    var initial_port: u16 = 0;
-    if (rand) |r| {
-        initial_port = r.intRangeAtMost(u16, 1024, 65000);
-    } else unreachable;
-
-    var initial_conn_res: ?SaprusMessage = null;
-    errdefer if (initial_conn_res) |c| c.deinit(allocator);
-
-    var sock = try network.Socket.create(.ipv4, .udp);
-    defer sock.close();
-
-    // Bind to 255.255.255.255:8888
-    const bind_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
-        .port = 8888,
-    };
-
-    // timeout 1s
-    try sock.setReadTimeout(1 * std.time.us_per_s);
-    try sock.bind(bind_addr);
-
-    const msg = try sendInitialConnection(payload, initial_port, allocator);
-
-    var response_buf: [4096]u8 = undefined;
-    _ = try sock.receive(&response_buf); // Ignore message that I sent.
-    const len = try sock.receive(&response_buf);
-
-    initial_conn_res = try SaprusMessage.fromBytes(response_buf[0..len], allocator);
-
-    // Complete handshake after awaiting response
-    try broadcastSaprusMessage(msg, randomPort(), allocator);
-
-    return initial_conn_res;
-}
-
-pub const SaprusMessage = @import("./saprus_message.zig").SaprusMessage;
-
-const std = @import("std");
-const Random = std.Random;
-const posix = std.posix;
-const mem = std.mem;
-
-const network = @import("network");
-
-const Allocator = mem.Allocator;

src/saprus_message.zig

@@ -1,211 +0,0 @@
-const base64Enc = std.base64.Base64Encoder.init(std.base64.standard_alphabet_chars, '=');
-const base64Dec = std.base64.Base64Decoder.init(std.base64.standard_alphabet_chars, '=');
-
-/// Type tag for SaprusMessage union.
-/// This is the first value in the actual packet sent over the network.
-pub const SaprusPacketType = enum(u16) {
-    relay = 0x003C,
-    file_transfer = 0x8888,
-    connection = 0x00E9,
-    _,
-};
-
-/// Reserved option values.
-/// Currently unused.
-pub const SaprusConnectionOptions = packed struct(u8) {
-    opt1: bool = false,
-    opt2: bool = false,
-    opt3: bool = false,
-    opt4: bool = false,
-    opt5: bool = false,
-    opt6: bool = false,
-    opt7: bool = false,
-    opt8: bool = false,
-};
-
-pub const SaprusError = error{
-    NotImplementedSaprusType,
-    UnknownSaprusType,
-};
-
-/// All Saprus messages
-pub const SaprusMessage = union(SaprusPacketType) {
-    pub const Relay = struct {
-        pub const Header = packed struct {
-            dest: @Vector(4, u8),
-        };
-        header: Header,
-        payload: []const u8,
-    };
-    pub const Connection = struct {
-        pub const Header = packed struct {
-            src_port: u16, // random number > 1024
-            dest_port: u16, // random number > 1024
-            seq_num: u32 = 0,
-            msg_id: u32 = 0,
-            reserved: u8 = 0,
-            options: SaprusConnectionOptions = .{},
-        };
-        header: Header,
-        payload: []const u8,
-    };
-    relay: Relay,
-    file_transfer: void, // unimplemented
-    connection: Connection,
-
-    /// Should be called for any SaprusMessage that was declared using a function that you pass an allocator to.
-    pub fn deinit(self: SaprusMessage, allocator: Allocator) void {
-        switch (self) {
-            .relay => |r| allocator.free(r.payload),
-            .connection => |c| allocator.free(c.payload),
-            else => unreachable,
-        }
-    }
-
-    fn toBytesAux(
-        header: anytype,
-        payload: []const u8,
-        buf: *std.ArrayList(u8),
-        allocator: Allocator,
-    ) !void {
-        const Header = @TypeOf(header);
-        // Create a growable string to store the base64 bytes in.
-        // Doing this first so I can use the length of the encoded bytes for the length field.
-        var payload_list = std.ArrayList(u8).init(allocator);
-        defer payload_list.deinit();
-        const buf_w = payload_list.writer();
-
-        // Write the payload bytes as base64 to the growable string.
-        try base64Enc.encodeWriter(buf_w, payload);
-
-        // At this point, payload_list contains the base64 encoded payload.
-
-        // Add the payload length to the output buf.
-        try buf.*.appendSlice(
-            asBytes(&nativeToBig(u16, @intCast(payload_list.items.len + @bitSizeOf(Header) / 8))),
-        );
-
-        // Add the header bytes to the output buf.
-        var header_buf: [@sizeOf(Header)]u8 = undefined;
-        var header_buf_stream = std.io.fixedBufferStream(&header_buf);
-        try header_buf_stream.writer().writeStructEndian(header, .big);
-        // Add the exact number of bits in the header without padding.
-        try buf.*.appendSlice(header_buf[0 .. @bitSizeOf(Header) / 8]);
-
-        try buf.*.appendSlice(payload_list.items);
-    }
-
-    /// Caller is responsible for freeing the returned bytes.
-    pub fn toBytes(self: SaprusMessage, allocator: Allocator) ![]u8 {
-        // Create a growable list of bytes to store the output in.
-        var buf = std.ArrayList(u8).init(allocator);
-        errdefer buf.deinit();
-
-        // Start with writing the message type, which is the first 16 bits of every Saprus message.
-        try buf.appendSlice(asBytes(&nativeToBig(u16, @intFromEnum(self))));
-
-        // Write the proper header and payload for the given packet type.
-        switch (self) {
-            .relay => |r| try toBytesAux(r.header, r.payload, &buf, allocator),
-            .connection => |c| try toBytesAux(c.header, c.payload, &buf, allocator),
-            .file_transfer => return SaprusError.NotImplementedSaprusType,
-        }
-
-        // Collect the growable list as a slice and return it.
-        return buf.toOwnedSlice();
-    }
-
-    fn fromBytesAux(
-        comptime packet: SaprusPacketType,
-        len: u16,
-        r: std.io.FixedBufferStream([]const u8).Reader,
-        allocator: Allocator,
-    ) !SaprusMessage {
-        const Header = @field(@FieldType(SaprusMessage, @tagName(packet)), "Header");
-
-        // Read the header for the current message type.
-        var header_bytes: [@sizeOf(Header)]u8 = undefined;
-        _ = try r.read(header_bytes[0 .. @bitSizeOf(Header) / 8]);
-        var header_stream = std.io.fixedBufferStream(&header_bytes);
-        const header = try header_stream.reader().readStructEndian(Header, .big);
-
-        // Read the base64 bytes into a list to be able to call the decoder on it.
-        const payload_buf = try allocator.alloc(u8, len - @bitSizeOf(Header) / 8);
-        defer allocator.free(payload_buf);
-        _ = try r.readAll(payload_buf);
-
-        // Create a buffer to store the payload in, and decode the base64 bytes into the payload field.
-        const payload = try allocator.alloc(u8, try base64Dec.calcSizeForSlice(payload_buf));
-        try base64Dec.decode(payload, payload_buf);
-
-        // Return the type of SaprusMessage specified by the `packet` argument.
-        return @unionInit(SaprusMessage, @tagName(packet), .{
-            .header = header,
-            .payload = payload,
-        });
-    }
-
-    /// Caller is responsible for calling .deinit on the returned value.
-    pub fn fromBytes(bytes: []const u8, allocator: Allocator) !SaprusMessage {
-        var s = std.io.fixedBufferStream(bytes);
-        const r = s.reader();
-
-        // Read packet type
-        const packet_type = @as(SaprusPacketType, @enumFromInt(try r.readInt(u16, .big)));
-
-        // Read the length of the header + base64 encoded payload.
-        const len = try r.readInt(u16, .big);
-
-        switch (packet_type) {
-            .relay => return fromBytesAux(.relay, len, r, allocator),
-            .connection => return fromBytesAux(.connection, len, r, allocator),
-            .file_transfer => return SaprusError.NotImplementedSaprusType,
-            else => return SaprusError.UnknownSaprusType,
-        }
-    }
-};
-
-const std = @import("std");
-const Allocator = std.mem.Allocator;
-
-const asBytes = std.mem.asBytes;
-const nativeToBig = std.mem.nativeToBig;
-
-test "Round trip Relay toBytes and fromBytes" {
-    const gpa = std.testing.allocator;
-    const msg = SaprusMessage{
-        .relay = .{
-            .header = .{ .dest = .{ 255, 255, 255, 255 } },
-            .payload = "Hello darkness my old friend",
-        },
-    };
-
-    const to_bytes = try msg.toBytes(gpa);
-    defer gpa.free(to_bytes);
-
-    const from_bytes = try SaprusMessage.fromBytes(to_bytes, gpa);
-    defer from_bytes.deinit(gpa);
-
-    try std.testing.expectEqualDeep(msg, from_bytes);
-}
-
-test "Round trip Connection toBytes and fromBytes" {
-    const gpa = std.testing.allocator;
-    const msg = SaprusMessage{
-        .connection = .{
-            .header = .{
-                .src_port = 0,
-                .dest_port = 0,
-            },
-            .payload = "Hello darkness my old friend",
-        },
-    };
-
-    const to_bytes = try msg.toBytes(gpa);
-    defer gpa.free(to_bytes);
-
-    const from_bytes = try SaprusMessage.fromBytes(to_bytes, gpa);
-    defer from_bytes.deinit(gpa);
-
-    try std.testing.expectEqualDeep(msg, from_bytes);
-}