startiing to clean up c api

Should map directly to the zig struct instead of mallocing

build.zig

@@ -1,4 +1,5 @@
 const std = @import("std");
+const Step = std.Build.Step;
 
 // Although this function looks imperative, note that its job is to
 // declaratively construct a build graph that will be executed by an external
@@ -15,6 +16,12 @@ pub fn build(b: *std.Build) void {
     // set a preferred release mode, allowing the user to decide how to optimize.
     const optimize = b.standardOptimizeOption(.{});
 
+    const lib_mod = b.createModule(.{
+        .root_source_file = b.path("src/root.zig"),
+        .target = target,
+        .optimize = optimize,
+    });
+
     // We will also create a module for our other entry point, 'main.zig'.
     const exe_mod = b.createModule(.{
         // `root_source_file` is the Zig "entry point" of the module. If a module
@@ -26,7 +33,34 @@ pub fn build(b: *std.Build) void {
         .optimize = optimize,
     });
 
-    exe_mod.addImport("network", b.dependency("network", .{}).module("network"));
+    lib_mod.addImport("network", b.dependency("network", .{}).module("network"));
+
+    exe_mod.addImport("zaprus", lib_mod);
+    exe_mod.addImport("clap", b.dependency("clap", .{}).module("clap"));
+
+    const static_lib = b.addLibrary(.{
+        .linkage = .static,
+        .name = "zaprus",
+        .root_module = lib_mod,
+    });
+    static_lib.addIncludePath(.{ .cwd_relative = "include" });
+    static_lib.linkLibC();
+
+    b.installArtifact(static_lib);
+
+    const dynamic_lib = b.addLibrary(.{
+        .linkage = .dynamic,
+        .name = "zaprus",
+        .root_module = lib_mod,
+    });
+    dynamic_lib.addIncludePath(.{ .cwd_relative = "include" });
+    dynamic_lib.linkLibC();
+
+    b.installArtifact(dynamic_lib);
+
+    // C Headers
+    const c_header = b.addInstallHeaderFile(b.path("include/zaprus.h"), "zaprus.h");
+    b.getInstallStep().dependOn(&c_header.step);
 
     // This creates another `std.Build.Step.Compile`, but this one builds an executable
     // rather than a static library.

build.zig.zon

@@ -40,6 +40,10 @@
             .url = "https://github.com/ikskuh/zig-network/archive/c76240d2240711a3dcbf1c0fb461d5d1f18be79a.zip",
             .hash = "network-0.1.0-AAAAAOwlAQAQ6zKPUrsibdpGisxld9ftUKGdMvcCSpaj",
         },
+        .clap = .{
+            .url = "git+https://github.com/Hejsil/zig-clap?ref=0.10.0#e47028deaefc2fb396d3d9e9f7bd776ae0b2a43a",
+            .hash = "clap-0.10.0-oBajB434AQBDh-Ei3YtoKIRxZacVPF1iSwp3IX_ZB8f0",
+        },
     },
     .paths = .{
         "build.zig",

include/zaprus.h

@@ -0,0 +1,15 @@
+// client
+
+#include<stdint.h>
+#include<stdlib.h>
+
+int zaprus_init(void);
+
+int zaprus_deinit(void);
+
+int zaprus_send_relay(const char* payload, size_t len, char dest[4]);
+
+int zaprus_send_initial_connection(const char* payload, size_t len, uint16_t initial_port);
+
+void* zaprus_connect(const char* payload, size_t len);
+

src/Client.zig

@@ -0,0 +1,124 @@
+var rand: ?Random = null;
+
+pub fn init() !void {
+    var prng = Random.DefaultPrng.init(blk: {
+        var seed: u64 = undefined;
+        try posix.getrandom(mem.asBytes(&seed));
+        break :blk seed;
+    });
+    rand = prng.random();
+    try network.init();
+}
+
+pub fn deinit() void {
+    network.deinit();
+}
+
+fn broadcastSaprusMessage(msg: SaprusMessage, udp_port: u16, allocator: Allocator) !void {
+    const msg_bytes = try msg.toBytes(allocator);
+    defer allocator.free(msg_bytes);
+
+    var sock = try network.Socket.create(.ipv4, .udp);
+    defer sock.close();
+
+    try sock.setBroadcast(true);
+
+    // Bind to 0.0.0.0:0
+    const bind_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.any },
+        .port = 0,
+    };
+
+    const dest_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
+        .port = udp_port,
+    };
+
+    try sock.bind(bind_addr);
+
+    _ = try sock.sendTo(dest_addr, msg_bytes);
+}
+
+pub fn sendRelay(payload: []const u8, dest: [4]u8, allocator: Allocator) !void {
+    const msg = SaprusMessage{
+        .relay = .{
+            .header = .{ .dest = dest },
+            .payload = payload,
+        },
+    };
+
+    try broadcastSaprusMessage(msg, 8888, allocator);
+}
+
+fn randomPort() u16 {
+    var p: u16 = 0;
+    if (rand) |r| {
+        p = r.intRangeAtMost(u16, 1024, 65000);
+    } else unreachable;
+
+    return p;
+}
+
+pub fn sendInitialConnection(payload: []const u8, initial_port: u16, allocator: Allocator) !SaprusMessage {
+    const dest_port = randomPort();
+    const msg = SaprusMessage{
+        .connection = .{
+            .header = .{
+                .src_port = initial_port,
+                .dest_port = dest_port,
+            },
+            .payload = payload,
+        },
+    };
+
+    try broadcastSaprusMessage(msg, 8888, allocator);
+
+    return msg;
+}
+
+pub fn connect(payload: []const u8, allocator: Allocator) !SaprusMessage {
+    var initial_port: u16 = 0;
+    if (rand) |r| {
+        initial_port = r.intRangeAtMost(u16, 1024, 65000);
+    } else unreachable;
+
+    var initial_conn_res: ?SaprusMessage = null;
+    errdefer if (initial_conn_res) |c| c.deinit(allocator);
+
+    var sock = try network.Socket.create(.ipv4, .udp);
+    defer sock.close();
+
+    // Bind to 255.255.255.255:8888
+    const bind_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
+        .port = 8888,
+    };
+
+    // timeout 1s
+    try sock.setReadTimeout(1 * std.time.us_per_s);
+    try sock.bind(bind_addr);
+
+    const msg = try sendInitialConnection(payload, initial_port, allocator);
+
+    var response_buf: [4096]u8 = undefined;
+    _ = try sock.receive(&response_buf); // Ignore message that I sent.
+    const len = try sock.receive(&response_buf);
+
+    initial_conn_res = try SaprusMessage.fromBytes(response_buf[0..len], allocator);
+
+    // Complete handshake after awaiting response
+    try broadcastSaprusMessage(msg, randomPort(), allocator);
+
+    return initial_conn_res.?;
+}
+
+const SaprusMessage = @import("message.zig").Message;
+
+const std = @import("std");
+const Random = std.Random;
+const posix = std.posix;
+const mem = std.mem;
+
+const network = @import("network");
+
+const Allocator = mem.Allocator;

src/c_api.zig

@@ -0,0 +1,32 @@
+// client
+export fn zaprus_init() c_int {
+    SaprusClient.init() catch return 1;
+    return 0;
+}
+
+export fn zaprus_deinit() c_int {
+    SaprusClient.deinit();
+    return 0;
+}
+
+export fn zaprus_send_relay(payload: [*]const u8, len: usize, dest: [*]u8) c_int {
+    SaprusClient.sendRelay(payload[0..len], dest[0..4].*, allocator) catch return 1;
+    return 0;
+}
+
+export fn zaprus_connect(payload: [*]const u8, len: usize, output: *SaprusConnection) c_int {
+    output.* = (SaprusClient.connect(payload[0..len], allocator) catch return 1).?;
+    return 0;
+}
+
+const std = @import("std");
+
+const zaprus = @import("./root.zig");
+const SaprusClient = zaprus.Client;
+const SaprusConnection = zaprus.Connection;
+
+const allocator = std.heap.c_allocator;
+
+test {
+    std.testing.refAllDeclsRecursively(@This());
+}

src/main.zig

@@ -1,113 +1,101 @@
 const is_debug = builtin.mode == .Debug;
-const base64 = std.base64.Base64Encoder.init(std.base64.standard_alphabet_chars, '=');
 
-const SaprusPacketType = enum(u16) {
-    relay = 0x003C,
-    file_transfer = 0x8888,
-    connection = 0x00E9,
-};
-
-const SaprusConnectionOptions = packed struct(u8) {
-    opt1: bool = false,
-    opt2: bool = false,
-    opt3: bool = false,
-    opt4: bool = false,
-    opt5: bool = false,
-    opt6: bool = false,
-    opt7: bool = false,
-    opt8: bool = false,
-};
-
-const SaprusMessage = union(SaprusPacketType) {
-    const Relay = struct {
-        header: packed struct {
-            dest: @Vector(4, u8),
-        },
-        payload: []const u8,
-    };
-    const Connection = struct {
-        header: packed struct {
-            src_port: u16,
-            dest_port: u16,
-            seq_num: u32 = 0,
-            msg_id: u32 = 0,
-            reserved: u8 = 0,
-            options: SaprusConnectionOptions = .{},
-        },
-        payload: []const u8,
-    };
-    relay: Relay,
-    file_transfer: void, // unimplemented
-    connection: Connection,
-
-    fn toBytes(self: SaprusMessage, allocator: Allocator) ![]u8 {
-        var buf = std.ArrayList(u8).init(allocator);
-        const w = buf.writer();
-        try w.writeInt(u16, @intFromEnum(self), .big);
-
-        switch (self) {
-            .relay => |r| {
-                try w.writeStructEndian(r.header, .big);
-                try w.writeInt(u16, @intCast(r.payload.len), .big);
-                try base64.encodeWriter(w, r.payload);
-            },
-            .file_transfer => unreachable,
-            .connection => |c| {
-                try w.writeStructEndian(c.header, .big);
-                try w.writeInt(u16, @intCast(c.payload.len), .big);
-                try base64.encodeWriter(w, c.payload);
-            },
-        }
-
-        return buf.toOwnedSlice();
-    }
-};
+/// This creates a debug allocator that can only be referenced in debug mode.
+/// You should check for is_debug around every reference to dba.
+var dba: DebugAllocator =
+    if (is_debug)
+        DebugAllocator.init
+    else
+        @compileError("Should not use debug allocator in release mode");
 
 pub fn main() !void {
-    const DBA = std.heap.DebugAllocator(.{});
-    var dba: ?DBA = if (comptime is_debug) DBA.init else null;
-    defer if (dba) |*d| {
-        _ = d.deinit();
+    defer if (is_debug) {
+        _ = dba.deinit();
     };
 
-    var allocator = if (dba) |*d| d.allocator() else std.heap.smp_allocator;
+    const gpa = if (is_debug) dba.allocator() else std.heap.smp_allocator;
 
-    const msg = SaprusMessage{
-        .relay = .{
-            .header = .{ .dest = .{ 255, 255, 255, 255 } },
-            .payload = "Hello darkness my old friend",
-        },
+    // CLI parsing adapted from the example here
+    // https://github.com/Hejsil/zig-clap/blob/e47028deaefc2fb396d3d9e9f7bd776ae0b2a43a/README.md#examples
+
+    // First we specify what parameters our program can take.
+    // We can use `parseParamsComptime` to parse a string into an array of `Param(Help)`.
+    const params = comptime clap.parseParamsComptime(
+        \\-h, --help           Display this help and exit.
+        \\-r, --relay <str>    A relay message to send.
+        \\-d, --dest <str>     An IPv4 or <= 4 ASCII byte string.
+        \\-c, --connect <str>  A connection message to send.
+        \\
+    );
+
+    // Initialize our diagnostics, which can be used for reporting useful errors.
+    // This is optional. You can also pass `.{}` to `clap.parse` if you don't
+    // care about the extra information `Diagnostics` provides.
+    var diag = clap.Diagnostic{};
+    var res = clap.parse(clap.Help, &params, clap.parsers.default, .{
+        .diagnostic = &diag,
+        .allocator = gpa,
+    }) catch |err| {
+        // Report useful error and exit.
+        diag.report(std.io.getStdErr().writer(), err) catch {};
+        return err;
     };
+    defer res.deinit();
 
-    const msg_bytes = try msg.toBytes(allocator);
-    defer allocator.free(msg_bytes);
+    try SaprusClient.init();
+    defer SaprusClient.deinit();
 
-    try network.init();
-    defer network.deinit();
+    if (res.args.help != 0) {
+        return clap.help(std.io.getStdErr().writer(), clap.Help, &params, .{});
+    }
 
-    var sock = try network.Socket.create(.ipv4, .udp);
-    defer sock.close();
-
-    try sock.setBroadcast(true);
-
-    // Bind to 0.0.0.0:0
-    const bind_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.any },
-        .port = 0,
+    if (res.args.relay) |r| {
+        const dest = parseDest(res.args.dest) catch .{ 70, 70, 70, 70 };
+        try SaprusClient.sendRelay(
+            if (r.len > 0) r else "Hello darkness my old friend",
+            dest,
+            gpa,
+        );
+        // std.debug.print("Sent: {s}\n", .{r});
+        return;
+    } else if (res.args.connect) |c| {
+        const conn_res: ?SaprusMessage = SaprusClient.connect(if (c.len > 0) c else "Hello darkness my old friend", gpa) catch |err| switch (err) {
+            error.WouldBlock => null,
+            else => return err,
         };
+        defer if (conn_res) |r| r.deinit(gpa);
+        if (conn_res) |r| {
+            std.debug.print("{s}\n", .{r.connection.payload});
+        } else {
+            std.debug.print("No response from connection request\n", .{});
+        }
+        return;
+    }
 
-    const dest_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
-        .port = 8888,
-    };
+    return clap.help(std.io.getStdErr().writer(), clap.Help, &params, .{});
+}
 
-    try sock.bind(bind_addr);
+fn parseDest(in: ?[]const u8) [4]u8 {
+    if (in) |dest| {
+        if (dest.len <= 4) {
+            var res: [4]u8 = @splat(0);
+            @memcpy(res[0..dest.len], dest);
+            return res;
+        }
 
-    _ = try sock.sendTo(dest_addr, msg_bytes);
+        const addr = std.net.Ip4Address.parse(dest, 0) catch return "FAIL".*;
+        return @bitCast(addr.sa.addr);
+    }
+    return "zap".*;
 }
 
 const builtin = @import("builtin");
 const std = @import("std");
-const Allocator = std.mem.Allocator;
+const DebugAllocator = std.heap.DebugAllocator(.{});
+const ArrayList = std.ArrayList;
 
-const network = @import("network");
+const zaprus = @import("zaprus");
+const SaprusClient = zaprus.Client;
+const SaprusMessage = zaprus.Message;
+
+const clap = @import("clap");

src/message.zig

@@ -0,0 +1,211 @@
+const base64Enc = std.base64.Base64Encoder.init(std.base64.standard_alphabet_chars, '=');
+const base64Dec = std.base64.Base64Decoder.init(std.base64.standard_alphabet_chars, '=');
+
+/// Type tag for Message union.
+/// This is the first value in the actual packet sent over the network.
+pub const PacketType = enum(u16) {
+    relay = 0x003C,
+    file_transfer = 0x8888,
+    connection = 0x00E9,
+    _,
+};
+
+/// Reserved option values.
+/// Currently unused.
+pub const ConnectionOptions = packed struct(u8) {
+    opt1: bool = false,
+    opt2: bool = false,
+    opt3: bool = false,
+    opt4: bool = false,
+    opt5: bool = false,
+    opt6: bool = false,
+    opt7: bool = false,
+    opt8: bool = false,
+};
+
+pub const Error = error{
+    NotImplementedSaprusType,
+    UnknownSaprusType,
+};
+
+/// All Saprus messages
+pub const Message = union(PacketType) {
+    pub const Relay = struct {
+        pub const Header = packed struct {
+            dest: @Vector(4, u8),
+        };
+        header: Header,
+        payload: []const u8,
+    };
+    pub const Connection = struct {
+        pub const Header = packed struct {
+            src_port: u16, // random number > 1024
+            dest_port: u16, // random number > 1024
+            seq_num: u32 = 0,
+            msg_id: u32 = 0,
+            reserved: u8 = 0,
+            options: ConnectionOptions = .{},
+        };
+        header: Header,
+        payload: []const u8,
+    };
+    relay: Relay,
+    file_transfer: void, // unimplemented
+    connection: Connection,
+
+    /// Should be called for any Message that was declared using a function that you pass an allocator to.
+    pub fn deinit(self: Message, allocator: Allocator) void {
+        switch (self) {
+            .relay => |r| allocator.free(r.payload),
+            .connection => |c| allocator.free(c.payload),
+            else => unreachable,
+        }
+    }
+
+    fn toBytesAux(
+        header: anytype,
+        payload: []const u8,
+        buf: *std.ArrayList(u8),
+        allocator: Allocator,
+    ) !void {
+        const Header = @TypeOf(header);
+        // Create a growable string to store the base64 bytes in.
+        // Doing this first so I can use the length of the encoded bytes for the length field.
+        var payload_list = std.ArrayList(u8).init(allocator);
+        defer payload_list.deinit();
+        const buf_w = payload_list.writer();
+
+        // Write the payload bytes as base64 to the growable string.
+        try base64Enc.encodeWriter(buf_w, payload);
+
+        // At this point, payload_list contains the base64 encoded payload.
+
+        // Add the payload length to the output buf.
+        try buf.*.appendSlice(
+            asBytes(&nativeToBig(u16, @intCast(payload_list.items.len + @bitSizeOf(Header) / 8))),
+        );
+
+        // Add the header bytes to the output buf.
+        var header_buf: [@sizeOf(Header)]u8 = undefined;
+        var header_buf_stream = std.io.fixedBufferStream(&header_buf);
+        try header_buf_stream.writer().writeStructEndian(header, .big);
+        // Add the exact number of bits in the header without padding.
+        try buf.*.appendSlice(header_buf[0 .. @bitSizeOf(Header) / 8]);
+
+        try buf.*.appendSlice(payload_list.items);
+    }
+
+    /// Caller is responsible for freeing the returned bytes.
+    pub fn toBytes(self: Message, allocator: Allocator) ![]u8 {
+        // Create a growable list of bytes to store the output in.
+        var buf = std.ArrayList(u8).init(allocator);
+        errdefer buf.deinit();
+
+        // Start with writing the message type, which is the first 16 bits of every Saprus message.
+        try buf.appendSlice(asBytes(&nativeToBig(u16, @intFromEnum(self))));
+
+        // Write the proper header and payload for the given packet type.
+        switch (self) {
+            .relay => |r| try toBytesAux(r.header, r.payload, &buf, allocator),
+            .connection => |c| try toBytesAux(c.header, c.payload, &buf, allocator),
+            .file_transfer => return Error.NotImplementedSaprusType,
+        }
+
+        // Collect the growable list as a slice and return it.
+        return buf.toOwnedSlice();
+    }
+
+    fn fromBytesAux(
+        comptime packet: PacketType,
+        len: u16,
+        r: std.io.FixedBufferStream([]const u8).Reader,
+        allocator: Allocator,
+    ) !Message {
+        const Header = @field(@FieldType(Message, @tagName(packet)), "Header");
+
+        // Read the header for the current message type.
+        var header_bytes: [@sizeOf(Header)]u8 = undefined;
+        _ = try r.read(header_bytes[0 .. @bitSizeOf(Header) / 8]);
+        var header_stream = std.io.fixedBufferStream(&header_bytes);
+        const header = try header_stream.reader().readStructEndian(Header, .big);
+
+        // Read the base64 bytes into a list to be able to call the decoder on it.
+        const payload_buf = try allocator.alloc(u8, len - @bitSizeOf(Header) / 8);
+        defer allocator.free(payload_buf);
+        _ = try r.readAll(payload_buf);
+
+        // Create a buffer to store the payload in, and decode the base64 bytes into the payload field.
+        const payload = try allocator.alloc(u8, try base64Dec.calcSizeForSlice(payload_buf));
+        try base64Dec.decode(payload, payload_buf);
+
+        // Return the type of Message specified by the `packet` argument.
+        return @unionInit(Message, @tagName(packet), .{
+            .header = header,
+            .payload = payload,
+        });
+    }
+
+    /// Caller is responsible for calling .deinit on the returned value.
+    pub fn fromBytes(bytes: []const u8, allocator: Allocator) !Message {
+        var s = std.io.fixedBufferStream(bytes);
+        const r = s.reader();
+
+        // Read packet type
+        const packet_type = @as(PacketType, @enumFromInt(try r.readInt(u16, .big)));
+
+        // Read the length of the header + base64 encoded payload.
+        const len = try r.readInt(u16, .big);
+
+        switch (packet_type) {
+            .relay => return fromBytesAux(.relay, len, r, allocator),
+            .connection => return fromBytesAux(.connection, len, r, allocator),
+            .file_transfer => return Error.NotImplementedSaprusType,
+            else => return Error.UnknownSaprusType,
+        }
+    }
+};
+
+const std = @import("std");
+const Allocator = std.mem.Allocator;
+
+const asBytes = std.mem.asBytes;
+const nativeToBig = std.mem.nativeToBig;
+
+test "Round trip Relay toBytes and fromBytes" {
+    const gpa = std.testing.allocator;
+    const msg = Message{
+        .relay = .{
+            .header = .{ .dest = .{ 255, 255, 255, 255 } },
+            .payload = "Hello darkness my old friend",
+        },
+    };
+
+    const to_bytes = try msg.toBytes(gpa);
+    defer gpa.free(to_bytes);
+
+    const from_bytes = try Message.fromBytes(to_bytes, gpa);
+    defer from_bytes.deinit(gpa);
+
+    try std.testing.expectEqualDeep(msg, from_bytes);
+}
+
+test "Round trip Connection toBytes and fromBytes" {
+    const gpa = std.testing.allocator;
+    const msg = Message{
+        .connection = .{
+            .header = .{
+                .src_port = 0,
+                .dest_port = 0,
+            },
+            .payload = "Hello darkness my old friend",
+        },
+    };
+
+    const to_bytes = try msg.toBytes(gpa);
+    defer gpa.free(to_bytes);
+
+    const from_bytes = try Message.fromBytes(to_bytes, gpa);
+    defer from_bytes.deinit(gpa);
+
+    try std.testing.expectEqualDeep(msg, from_bytes);
+}

src/root.zig

@@ -0,0 +1,4 @@
+pub const Client = @import("Client.zig");
+pub usingnamespace @import("message.zig");
+
+pub usingnamespace @import("c_api.zig");