Bad attempt at using @fieldParentPtr

https://kagi.com/assistant/a8f0a9ac-a11a-472e-af38-98d7e877e293

build.zig

@@ -15,6 +15,12 @@ pub fn build(b: *std.Build) void {
     // set a preferred release mode, allowing the user to decide how to optimize.
     const optimize = b.standardOptimizeOption(.{});
 
+    const lib_mod = b.createModule(.{
+        .root_source_file = b.path("src/root.zig"),
+        .target = target,
+        .optimize = optimize,
+    });
+
     // We will also create a module for our other entry point, 'main.zig'.
     const exe_mod = b.createModule(.{
         // `root_source_file` is the Zig "entry point" of the module. If a module
@@ -26,7 +32,19 @@ pub fn build(b: *std.Build) void {
         .optimize = optimize,
     });
 
-    exe_mod.addImport("network", b.dependency("network", .{}).module("network"));
+    lib_mod.addImport("network", b.dependency("network", .{}).module("network"));
+    lib_mod.addImport("gatorcat", b.dependency("gatorcat", .{}).module("gatorcat"));
+
+    exe_mod.addImport("zaprus", lib_mod);
+    exe_mod.addImport("clap", b.dependency("clap", .{}).module("clap"));
+
+    const lib = b.addLibrary(.{
+        .linkage = .static,
+        .name = "zaprus",
+        .root_module = lib_mod,
+    });
+
+    b.installArtifact(lib);
 
     // This creates another `std.Build.Step.Compile`, but this one builds an executable
     // rather than a static library.

build.zig.zon

@@ -40,6 +40,14 @@
             .url = "https://github.com/ikskuh/zig-network/archive/c76240d2240711a3dcbf1c0fb461d5d1f18be79a.zip",
             .hash = "network-0.1.0-AAAAAOwlAQAQ6zKPUrsibdpGisxld9ftUKGdMvcCSpaj",
         },
+        .clap = .{
+            .url = "git+https://github.com/Hejsil/zig-clap?ref=0.10.0#e47028deaefc2fb396d3d9e9f7bd776ae0b2a43a",
+            .hash = "clap-0.10.0-oBajB434AQBDh-Ei3YtoKIRxZacVPF1iSwp3IX_ZB8f0",
+        },
+        .gatorcat = .{
+            .url = "git+https://github.com/kj4tmp/gatorcat#bb1847f6c95852e7a0ec8c07870a948c171d5f98",
+            .hash = "gatorcat-0.3.2-WcrpTf1mBwDrmPaIhKCfLJO064v8Sjjn7DBq4CKZSgHH",
+        },
     },
     .paths = .{
         "build.zig",

src/Client.zig

@@ -0,0 +1,132 @@
+var rand: ?Random = null;
+
+pub fn init() !void {
+    var prng = Random.DefaultPrng.init(blk: {
+        var seed: u64 = undefined;
+        try posix.getrandom(mem.asBytes(&seed));
+        break :blk seed;
+    });
+    rand = prng.random();
+    try network.init();
+}
+
+pub fn deinit() void {
+    network.deinit();
+}
+
+fn broadcastSaprusMessage(msg: SaprusMessage, udp_port: u16, allocator: Allocator) !void {
+    const msg_bytes = try msg.toBytes(allocator);
+    defer allocator.free(msg_bytes);
+
+    var sock = try network.Socket.create(.ipv4, .udp);
+    defer sock.close();
+
+    try sock.setBroadcast(true);
+
+    // Bind to 0.0.0.0:0
+    const bind_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.any },
+        .port = 0,
+    };
+
+    const dest_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
+        .port = udp_port,
+    };
+
+    try sock.bind(bind_addr);
+
+    _ = try sock.sendTo(dest_addr, msg_bytes);
+}
+
+pub fn sendRelay(payload: []const u8, dest: [4]u8, allocator: Allocator) !void {
+    const msg = SaprusMessage{
+        .relay = .{
+            .header = .{ .dest = dest },
+            .payload = payload,
+        },
+    };
+
+    try broadcastSaprusMessage(msg, 8888, allocator);
+}
+
+fn randomPort() u16 {
+    var p: u16 = 0;
+    if (rand) |r| {
+        p = r.intRangeAtMost(u16, 1024, 65000);
+    } else unreachable;
+
+    return p;
+}
+
+pub fn sendInitialConnection(payload: []const u8, initial_port: u16, allocator: Allocator) !SaprusMessage {
+    const dest_port = randomPort();
+    const msg = SaprusMessage{
+        .connection = .{
+            .header = .{
+                .src_port = initial_port,
+                .dest_port = dest_port,
+            },
+            .payload = payload,
+        },
+    };
+
+    try broadcastSaprusMessage(msg, 8888, allocator);
+
+    return msg;
+}
+
+pub fn connect(payload: []const u8, allocator: Allocator) !?SaprusConnection {
+    var foo: gcat.nic.RawSocket = try .init("enp7s0"); // /proc/net/dev
+    defer foo.deinit();
+
+    var initial_port: u16 = 0;
+    if (rand) |r| {
+        initial_port = r.intRangeAtMost(u16, 1024, 65000);
+    } else unreachable;
+
+    var initial_conn_res: ?SaprusMessage = null;
+    errdefer if (initial_conn_res) |c| c.deinit(allocator);
+
+    var sock = try network.Socket.create(.ipv4, .udp);
+    defer sock.close();
+
+    // Bind to 255.255.255.255:8888
+    const bind_addr = network.EndPoint{
+        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
+        .port = 8888,
+    };
+
+    // timeout 1s
+    try sock.setReadTimeout(1 * std.time.us_per_s);
+    try sock.bind(bind_addr);
+
+    const msg = try sendInitialConnection(payload, initial_port, allocator);
+
+    var response_buf: [4096]u8 = undefined;
+    _ = try sock.receive(&response_buf); // Ignore message that I sent.
+    const len = try sock.receive(&response_buf);
+
+    initial_conn_res = try SaprusMessage.fromBytes(response_buf[0..len], allocator);
+
+    // Complete handshake after awaiting response
+    try broadcastSaprusMessage(msg, randomPort(), allocator);
+
+    if (false) {
+        return initial_conn_res.?;
+    }
+    return null;
+}
+
+const SaprusMessage = @import("message.zig").Message;
+const SaprusConnection = @import("Connection.zig");
+
+const std = @import("std");
+const Random = std.Random;
+const posix = std.posix;
+const mem = std.mem;
+
+const network = @import("network");
+const gcat = @import("gatorcat");
+
+const Allocator = mem.Allocator;

src/main.zig

@@ -1,113 +1,94 @@
 const is_debug = builtin.mode == .Debug;
-const base64 = std.base64.Base64Encoder.init(std.base64.standard_alphabet_chars, '=');
 
-const SaprusPacketType = enum(u16) {
-    relay = 0x003C,
-    file_transfer = 0x8888,
-    connection = 0x00E9,
-};
-
-const SaprusConnectionOptions = packed struct(u8) {
-    opt1: bool = false,
-    opt2: bool = false,
-    opt3: bool = false,
-    opt4: bool = false,
-    opt5: bool = false,
-    opt6: bool = false,
-    opt7: bool = false,
-    opt8: bool = false,
-};
-
-const SaprusMessage = union(SaprusPacketType) {
-    const Relay = struct {
-        header: packed struct {
-            dest: @Vector(4, u8),
-        },
-        payload: []const u8,
-    };
-    const Connection = struct {
-        header: packed struct {
-            src_port: u16,
-            dest_port: u16,
-            seq_num: u32 = 0,
-            msg_id: u32 = 0,
-            reserved: u8 = 0,
-            options: SaprusConnectionOptions = .{},
-        },
-        payload: []const u8,
-    };
-    relay: Relay,
-    file_transfer: void, // unimplemented
-    connection: Connection,
-
-    fn toBytes(self: SaprusMessage, allocator: Allocator) ![]u8 {
-        var buf = std.ArrayList(u8).init(allocator);
-        const w = buf.writer();
-        try w.writeInt(u16, @intFromEnum(self), .big);
-
-        switch (self) {
-            .relay => |r| {
-                try w.writeStructEndian(r.header, .big);
-                try w.writeInt(u16, @intCast(r.payload.len), .big);
-                try base64.encodeWriter(w, r.payload);
-            },
-            .file_transfer => unreachable,
-            .connection => |c| {
-                try w.writeStructEndian(c.header, .big);
-                try w.writeInt(u16, @intCast(c.payload.len), .big);
-                try base64.encodeWriter(w, c.payload);
-            },
-        }
-
-        return buf.toOwnedSlice();
-    }
-};
+/// This creates a debug allocator that can only be referenced in debug mode.
+/// You should check for is_debug around every reference to dba.
+var dba: DebugAllocator =
+    if (is_debug)
+        DebugAllocator.init
+    else
+        @compileError("Should not use debug allocator in release mode");
 
 pub fn main() !void {
-    const DBA = std.heap.DebugAllocator(.{});
-    var dba: ?DBA = if (comptime is_debug) DBA.init else null;
-    defer if (dba) |*d| {
-        _ = d.deinit();
+    defer if (is_debug) {
+        _ = dba.deinit();
     };
 
-    var allocator = if (dba) |*d| d.allocator() else std.heap.smp_allocator;
+    const gpa = if (is_debug) dba.allocator() else std.heap.smp_allocator;
 
-    const msg = SaprusMessage{
-        .relay = .{
-            .header = .{ .dest = .{ 255, 255, 255, 255 } },
-            .payload = "Hello darkness my old friend",
-        },
+    // CLI parsing adapted from the example here
+    // https://github.com/Hejsil/zig-clap/blob/e47028deaefc2fb396d3d9e9f7bd776ae0b2a43a/README.md#examples
+
+    // First we specify what parameters our program can take.
+    // We can use `parseParamsComptime` to parse a string into an array of `Param(Help)`.
+    const params = comptime clap.parseParamsComptime(
+        \\-h, --help           Display this help and exit.
+        \\-r, --relay <str>    A relay message to send.
+        \\-d, --dest <str>     An IPv4 or <= 4 ASCII byte string.
+        \\-c, --connect <str>  A connection message to send.
+        \\
+    );
+
+    // Initialize our diagnostics, which can be used for reporting useful errors.
+    // This is optional. You can also pass `.{}` to `clap.parse` if you don't
+    // care about the extra information `Diagnostics` provides.
+    var diag = clap.Diagnostic{};
+    var res = clap.parse(clap.Help, &params, clap.parsers.default, .{
+        .diagnostic = &diag,
+        .allocator = gpa,
+    }) catch |err| {
+        // Report useful error and exit.
+        diag.report(std.io.getStdErr().writer(), err) catch {};
+        return err;
     };
+    defer res.deinit();
 
-    const msg_bytes = try msg.toBytes(allocator);
-    defer allocator.free(msg_bytes);
+    try SaprusClient.init();
+    defer SaprusClient.deinit();
 
-    try network.init();
-    defer network.deinit();
+    if (res.args.help != 0) {
+        return clap.help(std.io.getStdErr().writer(), clap.Help, &params, .{});
+    }
 
-    var sock = try network.Socket.create(.ipv4, .udp);
-    defer sock.close();
+    if (res.args.relay) |r| {
+        const dest = parseDest(res.args.dest);
+        try SaprusClient.sendRelay(
+            if (r.len > 0) r else "Hello darkness my old friend",
+            dest,
+            gpa,
+        );
+        // std.debug.print("Sent: {s}\n", .{r});
+        return;
+    } else if (res.args.connect) |c| {
+        _ = SaprusClient.connect(if (c.len > 0) c else "Hello darkness my old friend", gpa) catch |err| switch (err) {
+            error.WouldBlock => null,
+            else => return err,
+        };
+    }
 
-    try sock.setBroadcast(true);
+    return clap.help(std.io.getStdErr().writer(), clap.Help, &params, .{});
+}
 
-    // Bind to 0.0.0.0:0
-    const bind_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.any },
-        .port = 0,
-    };
+fn parseDest(in: ?[]const u8) [4]u8 {
+    if (in) |dest| {
+        if (dest.len <= 4) {
+            var res: [4]u8 = @splat(0);
+            @memcpy(res[0..dest.len], dest);
+            return res;
+        }
 
-    const dest_addr = network.EndPoint{
-        .address = network.Address{ .ipv4 = network.Address.IPv4.broadcast },
-        .port = 8888,
-    };
-
-    try sock.bind(bind_addr);
-
-    _ = try sock.sendTo(dest_addr, msg_bytes);
+        const addr = std.net.Ip4Address.parse(dest, 0) catch return "FAIL".*;
+        return @bitCast(addr.sa.addr);
+    }
+    return "zap\x00".*;
 }
 
 const builtin = @import("builtin");
 const std = @import("std");
-const Allocator = std.mem.Allocator;
+const DebugAllocator = std.heap.DebugAllocator(.{});
+const ArrayList = std.ArrayList;
 
-const network = @import("network");
+const zaprus = @import("zaprus");
+const SaprusClient = zaprus.Client;
+const SaprusMessage = zaprus.Message;
+
+const clap = @import("clap");

src/message.zig

@@ -0,0 +1,415 @@
+const base64Enc = std.base64.Base64Encoder.init(std.base64.standard_alphabet_chars, '=');
+const base64Dec = std.base64.Base64Decoder.init(std.base64.standard_alphabet_chars, '=');
+
+/// Type tag for Message union.
+/// This is the first value in the actual packet sent over the network.
+pub const PacketType = enum(u16) {
+    relay = 0x003C,
+    file_transfer = 0x8888,
+    connection = 0x00E9,
+    _,
+};
+
+/// Reserved option values.
+/// Currently unused.
+pub const ConnectionOptions = packed struct(u8) {
+    opt1: bool = false,
+    opt2: bool = false,
+    opt3: bool = false,
+    opt4: bool = false,
+    opt5: bool = false,
+    opt6: bool = false,
+    opt7: bool = false,
+    opt8: bool = false,
+};
+
+pub const Error = error{
+    NotImplementedSaprusType,
+    UnknownSaprusType,
+    InvalidMessage,
+};
+
+// ZERO COPY STUFF
+// &payload could be a void value that is treated as a pointer to a [*]u8
+pub const ZeroCopyMessage = packed struct {
+    const Relay = packed struct {
+        dest: @Vector(4, u8),
+        payload: void,
+
+        pub fn getPayload(self: *align(@alignOf(ZeroCopyMessage)) Relay) []u8 {
+            // Cast the 'self' pointer (which points to the Relay header,
+            // located at the same memory as the parent's 'bytes' field)
+            // to a pointer to void, as required by @fieldParentPtr for a void field.
+            // Preserve the known alignment.
+            const self_as_void_ptr: *align(@alignOf(ZeroCopyMessage)) void = @ptrCast(self);
+
+            // Cast the resulting *void pointer to the parent type *ZeroCopyMessage.
+            // This cast performs the necessary alignment check.
+            const parent: *ZeroCopyMessage = @alignCast(@fieldParentPtr("bytes", self_as_void_ptr));
+
+            // The 'length' field in the parent ZeroCopyMessage contains
+            // the size of the header (Relay) + payload length.
+            const total_len = parent.length;
+
+            // Payload length = total_len - size of the Relay header
+            const payload_len = total_len - @sizeOf(Relay);
+
+            // The payload starts immediately after the fixed fields of the Relay struct.
+            // The address of the 'payload' field represents this starting point.
+            const payload_start_ptr: [*]u8 = @ptrCast(&self.payload);
+
+            // Return a slice from the payload start address with the calculated length.
+            return payload_start_ptr[0..payload_len];
+        }
+    };
+    const Connection = packed struct {
+        src_port: u16, // random number > 1024
+        dest_port: u16, // random number > 1024
+        seq_num: u32 = 0,
+        msg_id: u32 = 0,
+        reserved: u8 = 0,
+        options: ConnectionOptions = .{},
+        payload: void,
+
+        pub fn getPayload(self: *align(1) Connection) []u8 {
+            const len: *u16 = @ptrFromInt(@intFromPtr(self) - @sizeOf(u16));
+            return @as([*]u8, @ptrCast(&self.payload))[0 .. len.* - @sizeOf(Connection)];
+        }
+
+        fn nativeFromNetworkEndian(self: *align(1) Connection) Error!void {
+            self.src_port = bigToNative(@TypeOf(self.src_port), self.src_port);
+            self.dest_port = bigToNative(@TypeOf(self.dest_port), self.dest_port);
+            self.seq_num = bigToNative(@TypeOf(self.seq_num), self.seq_num);
+            self.msg_id = bigToNative(@TypeOf(self.msg_id), self.msg_id);
+        }
+
+        fn networkFromNativeEndian(self: *align(1) Connection) Error!void {
+            self.src_port = nativeToBig(@TypeOf(self.src_port), self.src_port);
+            self.dest_port = nativeToBig(@TypeOf(self.dest_port), self.dest_port);
+            self.seq_num = nativeToBig(@TypeOf(self.seq_num), self.seq_num);
+            self.msg_id = nativeToBig(@TypeOf(self.msg_id), self.msg_id);
+        }
+    };
+
+    const Self = @This();
+
+    type: PacketType,
+    length: u16,
+    bytes: void = {},
+
+    pub fn init(allocator: Allocator, comptime @"type": PacketType, payload_len: u16) !*Self {
+        const header_size = @sizeOf(switch (@"type") {
+            .relay => Relay,
+            .connection => Connection,
+            else => return error.Bad,
+        });
+        const size = payload_len + @sizeOf(Self) + header_size;
+        const bytes = try allocator.alignedAlloc(u8, @alignOf(Self), size);
+        const res: *Self = @ptrCast(bytes.ptr);
+        res.type = @"type";
+        res.length = payload_len + header_size;
+        return res;
+    }
+
+    pub fn deinit(self: *Self, allocator: Allocator) void {
+        allocator.free(self.asBytes());
+    }
+
+    fn getRelay(self: *Self) *align(@alignOf(Self)) Relay {
+        return std.mem.bytesAsValue(Relay, &self.bytes);
+    }
+    fn getConnection(self: *Self) *align(@alignOf(Self)) Connection {
+        return std.mem.bytesAsValue(Connection, &self.bytes);
+    }
+
+    pub fn getSaprusTypePayload(self: *Self) Error!(union(PacketType) {
+        relay: *align(@alignOf(Self)) Relay,
+        file_transfer: void,
+        connection: *align(@alignOf(Self)) Connection,
+    }) {
+        return switch (self.type) {
+            .relay => .{ .relay = self.getRelay() },
+            .connection => .{ .connection = self.getConnection() },
+            .file_transfer => Error.NotImplementedSaprusType,
+            else => Error.UnknownSaprusType,
+        };
+    }
+
+    pub fn nativeFromNetworkEndian(self: *Self) Error!void {
+        self.type = @enumFromInt(bigToNative(
+            @typeInfo(@TypeOf(self.type)).@"enum".tag_type,
+            @intFromEnum(self.type),
+        ));
+        self.length = bigToNative(@TypeOf(self.length), self.length);
+        switch (try self.getSaprusTypePayload()) {
+            .relay => {},
+            .connection => |*con| try con.*.nativeFromNetworkEndian(),
+            // We know other values are unreachable,
+            // because they would have returned an error from the switch condition.
+            else => unreachable,
+        }
+    }
+
+    pub fn networkFromNativeEndian(self: *Self) Error!void {
+        try switch (try self.getSaprusTypePayload()) {
+            .relay => {},
+            .connection => |*con| con.*.networkFromNativeEndian(),
+            .file_transfer => Error.NotImplementedSaprusType,
+            else => Error.UnknownSaprusType,
+        };
+        self.type = @enumFromInt(nativeToBig(
+            @typeInfo(@TypeOf(self.type)).@"enum".tag_type,
+            @intFromEnum(self.type),
+        ));
+        self.length = nativeToBig(@TypeOf(self.length), self.length);
+    }
+
+    pub fn bytesAsValueUnchecked(bytes: []align(@alignOf(Self)) u8) *Self {
+        return std.mem.bytesAsValue(Self, bytes);
+    }
+
+    pub fn bytesAsValue(bytes: []align(@alignOf(Self)) u8) !*Self {
+        const res = bytesAsValueUnchecked(bytes);
+        return switch (res.type) {
+            .relay, .connection => if (bytes.len == res.length + @sizeOf(Self))
+                res
+            else
+                Error.InvalidMessage,
+            .file_transfer => Error.NotImplementedSaprusType,
+            else => Error.UnknownSaprusType,
+        };
+    }
+
+    pub fn asBytes(self: *Self) []align(@alignOf(Self)) u8 {
+        const size = @sizeOf(Self) + self.length;
+        return @as([*]align(@alignOf(Self)) u8, @ptrCast(self))[0..size];
+    }
+};
+
+test "testing variable length zero copy struct" {
+    const gpa = std.testing.allocator;
+    const payload = "Hello darkness my old friend";
+
+    // Create a view of the byte slice as a ZeroCopyMessage
+    const zcm: *ZeroCopyMessage = try .init(gpa, .relay, payload.len);
+    defer zcm.deinit(gpa);
+    std.debug.print("outer: {*}\n", .{zcm});
+
+    {
+        // Set the message values
+        {
+            // These are both set by the init call.
+            // zcm.type = .relay;
+            // zcm.length = payload_len;
+        }
+        const relay = (try zcm.getSaprusTypePayload()).relay;
+        relay.dest = .{ 1, 2, 3, 4 };
+        @memcpy(relay.getPayload(), payload);
+    }
+
+    {
+        const bytes = zcm.asBytes();
+
+        // Print the message as hex using the network byte order
+        try zcm.networkFromNativeEndian();
+        // We know the error from nativeFromNetworkEndian is unreachable because
+        // it would have returned an error from networkFromNativeEndian.
+        defer zcm.nativeFromNetworkEndian() catch unreachable;
+        std.debug.print("network bytes: {x}\n", .{bytes});
+        std.debug.print("bytes len: {d}\n", .{bytes.len});
+    }
+
+    if (false) {
+        // Illegal behavior
+        std.debug.print("{any}\n", .{(try zcm.getSaprusTypePayload()).connection});
+    }
+
+    try std.testing.expectEqualDeep(zcm, try ZeroCopyMessage.bytesAsValue(zcm.asBytes()));
+}
+
+/// All Saprus messages
+pub const Message = union(PacketType) {
+    pub const Relay = struct {
+        pub const Header = packed struct {
+            dest: @Vector(4, u8),
+        };
+        header: Header,
+        payload: []const u8,
+    };
+    pub const Connection = struct {
+        pub const Header = packed struct {
+            src_port: u16, // random number > 1024
+            dest_port: u16, // random number > 1024
+            seq_num: u32 = 0,
+            msg_id: u32 = 0,
+            reserved: u8 = 0,
+            options: ConnectionOptions = .{},
+        };
+        header: Header,
+        payload: []const u8,
+    };
+    relay: Relay,
+    file_transfer: void, // unimplemented
+    connection: Connection,
+
+    /// Should be called for any Message that was declared using a function that you pass an allocator to.
+    pub fn deinit(self: Message, allocator: Allocator) void {
+        switch (self) {
+            .relay => |r| allocator.free(r.payload),
+            .connection => |c| allocator.free(c.payload),
+            else => unreachable,
+        }
+    }
+
+    fn toBytesAux(
+        header: anytype,
+        payload: []const u8,
+        buf: *std.ArrayList(u8),
+        allocator: Allocator,
+    ) !void {
+        const Header = @TypeOf(header);
+        // Create a growable string to store the base64 bytes in.
+        // Doing this first so I can use the length of the encoded bytes for the length field.
+        var payload_list = std.ArrayList(u8).init(allocator);
+        defer payload_list.deinit();
+        const buf_w = payload_list.writer();
+
+        // Write the payload bytes as base64 to the growable string.
+        try base64Enc.encodeWriter(buf_w, payload);
+
+        // At this point, payload_list contains the base64 encoded payload.
+
+        // Add the payload length to the output buf.
+        try buf.*.appendSlice(
+            asBytes(&nativeToBig(u16, @intCast(payload_list.items.len + @bitSizeOf(Header) / 8))),
+        );
+
+        // Add the header bytes to the output buf.
+        var header_buf: [@sizeOf(Header)]u8 = undefined;
+        var header_buf_stream = std.io.fixedBufferStream(&header_buf);
+        try header_buf_stream.writer().writeStructEndian(header, .big);
+        // Add the exact number of bits in the header without padding.
+        try buf.*.appendSlice(header_buf[0 .. @bitSizeOf(Header) / 8]);
+
+        try buf.*.appendSlice(payload_list.items);
+    }
+
+    /// Caller is responsible for freeing the returned bytes.
+    pub fn toBytes(self: Message, allocator: Allocator) ![]u8 {
+        // Create a growable list of bytes to store the output in.
+        var buf = std.ArrayList(u8).init(allocator);
+        errdefer buf.deinit();
+
+        // Start with writing the message type, which is the first 16 bits of every Saprus message.
+        try buf.appendSlice(asBytes(&nativeToBig(u16, @intFromEnum(self))));
+
+        // Write the proper header and payload for the given packet type.
+        switch (self) {
+            .relay => |r| try toBytesAux(r.header, r.payload, &buf, allocator),
+            .connection => |c| try toBytesAux(c.header, c.payload, &buf, allocator),
+            .file_transfer => return Error.NotImplementedSaprusType,
+        }
+
+        // Collect the growable list as a slice and return it.
+        return buf.toOwnedSlice();
+    }
+
+    fn fromBytesAux(
+        comptime packet: PacketType,
+        len: u16,
+        r: std.io.FixedBufferStream([]const u8).Reader,
+        allocator: Allocator,
+    ) !Message {
+        const Header = @field(@FieldType(Message, @tagName(packet)), "Header");
+
+        // Read the header for the current message type.
+        var header_bytes: [@sizeOf(Header)]u8 = undefined;
+        _ = try r.read(header_bytes[0 .. @bitSizeOf(Header) / 8]);
+        var header_stream = std.io.fixedBufferStream(&header_bytes);
+        const header = try header_stream.reader().readStructEndian(Header, .big);
+
+        // Read the base64 bytes into a list to be able to call the decoder on it.
+        const payload_buf = try allocator.alloc(u8, len - @bitSizeOf(Header) / 8);
+        defer allocator.free(payload_buf);
+        _ = try r.readAll(payload_buf);
+
+        // Create a buffer to store the payload in, and decode the base64 bytes into the payload field.
+        const payload = try allocator.alloc(u8, try base64Dec.calcSizeForSlice(payload_buf));
+        try base64Dec.decode(payload, payload_buf);
+
+        // Return the type of Message specified by the `packet` argument.
+        return @unionInit(Message, @tagName(packet), .{
+            .header = header,
+            .payload = payload,
+        });
+    }
+
+    /// Caller is responsible for calling .deinit on the returned value.
+    pub fn fromBytes(bytes: []const u8, allocator: Allocator) !Message {
+        var s = std.io.fixedBufferStream(bytes);
+        const r = s.reader();
+
+        // Read packet type
+        const packet_type = @as(PacketType, @enumFromInt(try r.readInt(u16, .big)));
+
+        // Read the length of the header + base64 encoded payload.
+        const len = try r.readInt(u16, .big);
+
+        switch (packet_type) {
+            .relay => return fromBytesAux(.relay, len, r, allocator),
+            .connection => return fromBytesAux(.connection, len, r, allocator),
+            .file_transfer => return Error.NotImplementedSaprusType,
+            else => return Error.UnknownSaprusType,
+        }
+    }
+};
+
+const std = @import("std");
+const Allocator = std.mem.Allocator;
+
+const asBytes = std.mem.asBytes;
+const nativeToBig = std.mem.nativeToBig;
+const bigToNative = std.mem.bigToNative;
+
+test "Round trip Relay toBytes and fromBytes" {
+    const gpa = std.testing.allocator;
+    const msg = Message{
+        .relay = .{
+            .header = .{ .dest = .{ 255, 255, 255, 255 } },
+            .payload = "Hello darkness my old friend",
+        },
+    };
+
+    const to_bytes = try msg.toBytes(gpa);
+    defer gpa.free(to_bytes);
+
+    const from_bytes = try Message.fromBytes(to_bytes, gpa);
+    defer from_bytes.deinit(gpa);
+
+    try std.testing.expectEqualDeep(msg, from_bytes);
+}
+
+test "Round trip Connection toBytes and fromBytes" {
+    const gpa = std.testing.allocator;
+    const msg = Message{
+        .connection = .{
+            .header = .{
+                .src_port = 0,
+                .dest_port = 0,
+            },
+            .payload = "Hello darkness my old friend",
+        },
+    };
+
+    const to_bytes = try msg.toBytes(gpa);
+    defer gpa.free(to_bytes);
+
+    const from_bytes = try Message.fromBytes(to_bytes, gpa);
+    defer from_bytes.deinit(gpa);
+
+    try std.testing.expectEqualDeep(msg, from_bytes);
+}
+
+test {
+    std.testing.refAllDeclsRecursive(@This());
+}

src/root.zig

@@ -0,0 +1,4 @@
+pub const Client = @import("Client.zig");
+pub const Connection = @import("Connection.zig");
+
+pub usingnamespace @import("message.zig");